ПРОГРАММИРОВАНИЕ КЛАВИАТУРЫ

Стандартная функция ReadKey

стандартная функция readKey из системного модуля Crt. Функция вызывается без параметров, возвращает значение символьного типа и работает следующим образом. Организуется задержка выполнения с ожиданием нажатия клавиши. После того, как нажатие произведено, функция завершает работу, возвращая код нажатой клавиши. Полученное значение можно использовать далее в программе.

Функция readKey не отображает введенный символ на экран, благодаря чему она широко используется для организации управления в различных диалоговых программах. В дополнение к этому readKey позволяет отслеживать нажатие более широкого множества клавиш, опознавая функциональные и редактирующие клавиши и их сочетания с управляющими клавишами Ctrl, Alt, Shift.

Если говорить более подробно, функция readKey исходит из того, что все множество клавиш и их сочетаний с управляющими клавишами разбито на два подмножества, которые обычно называют основным и расширенным наборами.

В основной набор входят клавиши букв, цифр, разделителей и знаков препинания, их комбинации с клавишей Shift (или, что то же самое, при включенном переключателе CapsLock), а также клавиши Tab, BackSpace, Enter и Esc. Если нажата одна из перечисленных клавиш, то readKey возвратит обычный ASCII-код соответствующего символа.

В расширенном наборе содержатся некоторые (не все) клавиши из основного набора в комбинации с клавишами Ctrl и Alt, а также функциональные и редактирующие клавиши. Если нажимается одна из клавиш расширенного набора, то функция readKey возвращает символ с кодом 0 (его представление в программе – chr(0) или #0). В этом случае повторное обращение к readKey вернет код клавиши из расширенного набора.

Коды клавиш из основного и расширенного наборов в виде, удобном для включения в Турбо Паскаль-программы, приведены в приложении.

Схема использования функции readKey для общего случая может выглядеть так: (EXE-файл)

Program UsereadKey2;

 Uses

   Crt;

 Var

   Sym : Char;

 Begin

   ClrScr;

   while true do

     begin

       write ('Нажмите клавишу');

       Sym := readKey;

       if Sym <> #0

         then

           begin {основной набор}

             case Sym of

               #8 : writeln ('Вы нажали BackSpace');

               #9 : writeln ('Вы нажали Tab');

               #13 : writeln ('Вы нажали Enter');

               #27 : writeln ('Вы нажали Esc');

             else

               writeln ('Вы ввели символ ',Sym);

             end;

             if Sym = #27

               Then

                 Exit

           end

       else

         begin {расширенный набор}

           Sym := readKey;{повт. чтение: берем расширенный код}

           writeln ('Вы нажали клавишу с кодом ', Ord (Sym));

         end

     end

 End.

Большинство прикладных диалоговых программ использует описанную технику взаимодействия с клавиатурой. Однако встречаются случаи, когда возможностей функции readKey оказывается недостаточно. На самом деле функция readKey воспринимает нажатия не всех клавиш: достаточно попробовать, запустив вышеприведенную программу, нажать клавиши F11, F12, ввести комбинацию Alt+Esc и т.д.

Стандартная функция KeyPressed

Второй базовой функцией взаимодействия с клавиатурой является функция KeyPressed. В отличие от readKey, она предназначена не для приема кода нажатой клавиши, а для простой проверки, была ли нажата какая-либо клавиша. Эта функция вызывается без параметров и возвращает значение булевого типа: True, если было нажатие, и False в противном случае.

Важно понять, что KeyPressed не производит никаких действий с кодом нажатой клавиши, но код может быть далее прочитан функцией readKey, например,

. . .

 if KeyPressed

   then

     S := readKey;

 . . .

Графика в Паскале

ПРОГРАММИРОВАНИЕ КЛАВИАТУРЫ

Стандартная функция ReadKey

Стандартная функция KeyPressed